0 REM << RR21-2 >>
1 PRINT"[147]":POKE53280,0:POKE53281,6:POKE646,1
2 PRINT"-- DICE ANALYZER --"
3 REM  RUPERT REPORT #21
4 REM
5 PRINT"ENUMERATE ALL POSSIBLE"
6 PRINT"OUTCOMES FOR ROLLING THREE DICE"
7 REM
8 PRINT">>CALCULATE THE PROBABILITY THAT"
10 PRINT"  1) 3 ONES ARE ROLLED"
11 PRINT"  2) AT LEAST 1 THREE AND 1 SIX              ARE ROLLED"
12 PRINT"  3) NO TWOS ARE ROLLED"
13 PRINT"  4) THE SUM IS ELEVEN"
14 PRINT"    PRESS ANY KEY";:INPUT A$
15 REM >ON THE NTH ROLL (N = 1 TO 216):
16 REM ROLL(N,Y) = DIE Y'S VALUE
17 REM CT(N,Z) = # DICE WITH VALUE Z
18 REM TTL(N) = SUM OF DICE VALUES
19 REM
20 DIM ROLL(216,3),CT(216,6),TTL(216),RNUM(216)
30 N=1 : M=1 : PRINT CHR$(147)
40 FOR A=1 TO 6 : FOR B=1 TO 6
50 FOR C=1 TO 6
60 PRINT A;B;C
70 ROLL(N,1)=A:ROLL(N,2)=B:ROLL(N,3)=C
80 CT(N,A)=CT(N,A)+1 :CT(N,B)=CT(N,B)+1
90 CT(N,C)=CT(N,C)+1
100 TTL(N)=A+B+C
110 N=N+1 : NEXT C : NEXT B : NEXT A
120 PRINT"CALCULATING ... "
130 FOR N=1 TO 216
140 :IF CT(N,1)=3 THEN T1=T1+1
150 :IF CT(N,3)>=1 AND CT(N,6)>=1 THEN T2=T2+1
160 :IF CT(N,2)=0 THEN T3=T3+1
170 :IF TTL(N)=11 THEN T4=T4+1:RNUM(M)=N:M=M+1
180 NEXT N
190 PRINT
200 PRINT,"# SUCCESS"," % PROBABILITY"
210 PRINT "TEST 1",T1,T1*100/216
220 PRINT "TEST 2",T2,T2*100/216
230 PRINT "TEST 3",T3,T3*100/216
240 PRINT "TEST 4",T4,T4*100/216
250 PRINT
260 PRINT"SUCCESSFUL ROLLS FOR TEST 4:"
270 FOR M=1 TO T4
280 RM=RNUM(M)
290 PRINT ROLL(RM,1);ROLL(RM,2);ROLL(RM,3),
300 NEXT M